NXP SST Models

Please check product availability before design-in

2PB709ARL

*
.SUBCKT 2PB709ARL 1 2 3
*
* PNP transistor in SOT23
* Ic= 100 mA
* Vceo= 45 V
*
*
* TOPVIEW: 
*
*          C
*          |
*     _____3_____ 
*    |           |
*    |           |  SOT23
*    |           |
*    |___________|
*       1     2
*       |     |
*       B     E
*       
*
* housing parasitics
LBlead 11 111 3.5E-10
LE 2 22 1.12E-09
LC 3 33 2.3E-10
LBbond 1 11 9E-10
CBCG 33 111 6.2E-14
CBEG 22 111 4.5E-14
CCEG 22 33 6.2E-14
*
Q1 33 111 22 MAIN
D1 33 111 DIODE
*
*The diode does not reflect a 
*physical device but improves 
*only modeling in the reverse 
*mode of operation.
*
.MODEL MAIN PNP 
+ IS = 1.812E-014 
+ NF = 0.9965 
+ ISE = 1.531E-015 
+ NE = 1.371 
+ BF = 243.3 
+ IKF = 0.055 
+ VAF = 15 
+ NR = 0.995 
+ ISC = 5.561E-015 
+ NC = 1.119 
+ BR = 11.27 
+ IKR = 0.019 
+ VAR = 15 
+ RB = 67 
+ IRB = 0.0003 
+ RBM = 6 
+ RE = 0.5449 
+ RC = 0.53 
+ XTB = 0 
+ EG = 1.11 
+ XTI = 3 
+ CJE = 1.102E-011 
+ VJE = 0.795 
+ MJE = 0.4 
+ TF = 8.2E-010 
+ XTF = 17 
+ VTF = 5 
+ ITF = 0.4 
+ PTF = 0 
+ CJC = 6.031E-012 
+ VJC = 0.65 
+ MJC = 0.545 
+ XCJC = 1 
+ TR = 3.2E-008 
+ CJS = 0 
+ VJS = 0.75 
+ MJS = 0.333 
+ FC = 0.78 
.MODEL DIODE D 
+ IS = 4.455E-017 
+ N = 4.786 
+ BV = 1000 
+ IBV = 0.001 
+ RS = 205.4 
+ CJO = 0 
+ VJ = 1 
+ M = 0.5 
+ FC = 0 
+ TT = 0 
+ EG = 1.11 
+ XTI = 3 
.ENDS
View this model