NXP Complex Discretes Models

Please check product availability before design-in

PBLS6022D

*
.SUBCKT PBLS6022D 1 2 3 4 5 6
*
***************************************************************
*
* NXP Semiconducters
*
* 1 Low VCEsat (BISS) Transistor / 1 Resistor-Equipped 
* Transistor in SOT 457 package
*
* TR1       = Low VCEsat Transistor 
* Polarity  = PNP    
* Ic        = -1,5 A
* Vceo      = -60V
* hFE	    = typical 285 @VCE = -2 V;IC = -100 mA
* 
* TR2       = Resistor Equipped Transistor (RET)
* Polarity  = NPN
* Resistors = 4,7kO / 4,7 kO
* Ic        = 100mA
* Vceo      = 50V
* hFE	    = min 30 @VCE = 5 V;IC = 10 mA
* 
* Extraction date (week/year): 03/09 
* Simulator: Spice 3
*
* TOPVIEW: 
*
*      E1  C1  E2
*      |   |   |
*     _6___5___4_ 
*    |           |
*    |           |  SOT457
*    |           |
*    |___________|
*      1   2   3
*      |   |   |
*      B1  B2  C2
*
***************************************************************
*
R1 2 22 4.7E+03
Cres1 2 3 4.3E-13 
R21 22 44 2.35E+03
R22 44 4 2.35E+03
Cres2 44 3 1.4E-13
*
Q1 5 1 6 TR1
Q2 3 22 4 TR2 
D1 5 1 DIODE 
*
.MODEL TR1 PNP 
+ IS = 4.317E-013 
+ NF = 0.9862 
+ ISE = 1.138E-013 
+ NE = 1.441 
+ BF = 305 
+ IKF = 1.6 
+ VAF = 2.1 
+ NR = 0.9865 
+ ISC = 1.118E-012 
+ NC = 1.297 
+ BR = 50 
+ IKR = 1.9 
+ VAR = 10 
+ RB = 13.5 
+ IRB = 0.0008 
+ RBM = 0.75 
+ RE = 0.038 
+ RC = 0.035 
+ XTB = 0 
+ EG = 1.11 
+ XTI = 3 
+ CJE = 3.11E-010 
+ VJE = 0.8442 
+ MJE = 0.4135 
+ TF = 1.5E-009 
+ XTF = 5 
+ VTF = 1 
+ ITF = 1.2 
+ PTF = 0 
+ CJC = 9.25E-011 
+ VJC = 0.7292 
+ MJC = 0.4313 
+ XCJC = 1 
+ TR = 5E-009 
+ CJS = 0 
+ VJS = 0.75 
+ MJS = 0.333 
+ FC = 0.8 
*
.MODEL DIODE D 
+ IS = 1.159E-015 
+ N = 0.8542 
+ BV = 1000 
+ IBV = 0.001 
+ RS = 444.2 
+ CJO = 0 
+ VJ = 1 
+ M = 0.5 
+ FC = 0 
+ TT = 0 
+ EG = 1.11 
+ XTI = 3 
*
.MODEL TR2 NPN 
+ IS = 1.822E-14 
+ NF = 0.9932 
+ ISE = 2.894E-16 
+ NE = 1.4 
+ BF = 354.4 
+ IKF = 0.246 
+ VAF = 182 
+ NR = 0.9931 
+ ISC = 9.982E-12 
+ NC = 1.763 
+ BR = 14.99 
+ IKR = 0.05
+ VAR = 17.9 
+ RB = 10 
+ IRB = 5E-06 
+ RBM = 5 
+ RE = 0.649 
+ RC = 1.101 
+ XTB = 0 
+ EG = 1.11 
+ XTI = 3 
+ CJE = 1.32E-11 
+ VJE = 0.8401 
+ MJE = 0.3622 
+ TF = 1E-32 
+ XTF = 0 
+ VTF = 1E+03 
+ ITF = 0 
+ PTF = 0 
+ CJC = 3.821E-12 
+ VJC = 0.5986 
+ MJC = 0.3745 
+ XCJC = 0.6193 
+ TR = 1E-32
+ CJS = 0 
+ VJS = 0.75 
+ MJS = 0.333 
+ FC = 0.5
.ENDS
*
View this model