NXP SST Models

Please check product availability before design-in

BCW61D

.SUBCKT BCW61D 1 2 3 
*
**********************************************************
*
* NXP Semiconductors
*
* General purpose PNP transistor
* Ic   = 100 mA
* Vceo = 32   V 
* hFE  = 100  @ 5V/10 ?A (min)
* 
* Extraction date (week/year): 02/2009 
* Simulator: Spice 3
*
* TOPVIEW: 
*
*          C
*          |
*     _____3_____ 
*    |           |
*    |           |  SOT23
*    |           |
*    |___________|
*       1     2
*       |     |
*       B     E
*
* Diode D1, transistor Q2 and resistor RQ 
* are dedicated to improve modeling of quasi
* saturation area and reverse mode operation
* and do not reflect physical devices.
*
**********************************************************
*
* housing parasitics
LBlead 11 111 3.5E-10
LE 2 22 1.12E-09
LC 3 33 2.3E-10
LBbond 1 11 9E-10
CBCG 33 111 6.2E-14
CBEG 22 111 4.5E-14
CCEG 22 33 6.2E-14
*
Q1 33 111 22 MAIN AREA = 0.9196 
Q3 333 111 22 MAIN AREA = 0.08035
D1 333 111 DIODE 
RQ 333 33 111.9
*
.MODEL MAIN PNP 
+ IS = 1.619E-014 
+ NF = 0.9835 
+ ISE = 7.218E-015 
+ NE = 1.521 
+ BF = 266.9 
+ IKF = 0.08202 
+ VAF = 12.88 
+ NR = 0.977 
+ ISC = 3.672E-015 
+ NC = 1.122 
+ BR = 10.73 
+ IKR = 0.03072 
+ VAR = 24.01 
+ RB = 39.4 
+ IRB = 0.0001272 
+ RBM = 1.321 
+ RE = 0.3 
+ RC = 0.5566 
+ XTB = 0 
+ EG = 1.11 
+ XTI = 3 
+ CJE = 1.14E-011 
+ VJE = 0.7923 
+ MJE = 0.4031 
+ TF = 9E-010 
+ XTF = 20 
+ VTF = 5 
+ ITF = 0.52 
+ PTF = 0 
+ CJC = 5.839E-012 
+ VJC = 1 
+ MJC = 0.5758 
+ XCJC = 1 
+ TR = 1E-009 
+ CJS = 0 
+ VJS = 0.75 
+ MJS = 0.333 
+ FC = 0.79
*
.MODEL DIODE D 
+ IS = 5.409E-017 
+ N = 0.9852 
+ BV = 1000 
+ IBV = 0.001 
+ RS = 2.939 
+ CJO = 0 
+ VJ = 1 
+ M = 0.5 
+ FC = 0 
+ TT = 0 
+ EG = 1.11 
+ XTI = 3 
.ENDS
View this model